Удалить ложные активные сессии с помощью скрипта

Нет комментариев от MT?

Я написал этот скрипт, надеюсь, он поможет  
# вер. 1.0   2013-09-06  
# вер. 1.1   2013-11-01 - решена проблема с тем, что в конце месяца все сессии убивались  
#                       - добавлен лог с предупреждением о убитых сессиях  
# вер. 1.2   2014-03-09 - GMToffset не нужен в версии 6.10 и выше (возможно, в 6.x)  
#  
# СКРИПТ:  radius-close-inactive-sessions  
# ЦЕЛЬ: закрывать сессии, которые активны в radius, но у которых last-seen старее чем $actTimeout  
#          обычно происходит, когда клиентская сторона теряет связь с radius, а пользователь уходит из хотспота  
#------------------------------------------------------------------------------

# настройки  
# --------  
# включить отладку { false | true }  
local debug true  
# через сколько секунд бездействия убивать сессию  
local actTimeout (10*60)  
# смещение от GMT - в User Manager 6.10 и выше не нужно, должно быть 0  
local GMToffset [/system clock get gmt-offset]
if ( [/system clock get dst-active] != yes ) do={ :set GMToffset ( $GMToffset - 3600 ) }
local GMToffset 0  


# переменные  
# ---------  
local sessions  
local testD [/system clock get date]
local testDayOfMonth [:pick $testD 4 6]
local testT [/system clock get time]
local testTsec ( ($testDayOfMonth*24*3600) + [:pick $testT 0 2]*3600 + [:pick $testT 3 5]*60 + [:pick $testT 6 8] )

:set sessions [/tool user-manager session find where active=yes]

if ($debug = true) do={  
 :put ("testD: " . $testD)  
 :put ("testDayOfMonth: " . $testDayOfMonth )  
 :put ("testT: " . $testT)  
 :put ("testTsec: " . $testTsec)  
 :put ("Sessions: " . [:len $sessions])
}  

foreach session in $sessions do={  
 :local userName [/tool user-manager session get $session user ]
 :local uptime [/tool user-manager session get $session uptime ]
 :local hostIP [/tool user-manager session get $session "host-ip" ]
 :local lastSeen [/tool user-manager user get $userName last-seen ]

 local lastActD [:pick $lastSeen 0 11]
 local lastActDayOfMonth [:pick $lastSeen 4 6]
 local lastActT [:totime [:pick $lastSeen 12 20]]

 local lastActTsec ( ($lastActDayOfMonth*24*3600) + [:pick $lastActT 0 2]*3600 + [:pick $lastActT 3 5]*60 + [:pick $lastActT 6 8] )

 if ($debug = true) do={  
   :put ("id=".$session . " " . " пользователь " . $userName . " uptime  " . $uptime . " lastSeen " . $lastSeen . " hostIP ". $hostIP)  
   :put ("lastActD: " . $lastActD)  
   :put ("lastActDayOfMonth: " . $lastActDayOfMonth)  
   :put ("lastActT: " . $lastActT)  
   :put ("lastActTsec: " . $lastActTsec)  
 }  
 :set lastActTsec ($lastActTsec + $GMToffset)  
 if ($debug = true) do={  
   :put ("lastActTsec после коррекции GMT: " . $lastActTsec)  
 }  

# убеждаемся, что сейчас минимум конец месяца + $actTimeout  
 if ( $testTsec > $actTimeout) do={  
# разница больше $actTimeout, но меньше 27 дней (новый месяц)  
# из-за локального времени - GMT скрипт будет неэффективен раз в месяц  
   if ( (($testTsec - $lastActTsec) > $actTimeout) and (($testTsec - $lastActTsec) < 27*3600*24) ) do={  
     if ($debug = true) do={  
       :put ("radius неактивная сессия удалена, разница " . ($testTsec - $lastActTsec) . " сек., actTimeout=" . $actTimeout . " сек.")  
     }  
     /tool user-manager session close-session $session  
     :log warning ("radius неактивная сессия удалена, разница " . ($testTsec - $lastActTsec) . " пользователь " . $userName . " uptime  " . $uptime . " lastSeen " . $lastSeen . " hostIP ". $hostIP)  
   } else={  
     if ($debug = true) do={  
       :put ("Нет нужды убивать сессию, разница " . ($testTsec - $lastActTsec) . " сек., actTimeout=" . $actTimeout . " сек.")  
     }  
   }  
 }  
}

Я обновил код для RouterOS 6.x

Можешь, пожалуйста, выложить здесь обновлённый скрипт? Я пользуюсь RouterOS 6.49.6.