Mikrotik.moscow [тема: PUSHOVER — готовый скрипт для MikroTik для отправки сообщений]

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Tue, 09 Jul 2024 09:57:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Спасибо за это. Ни один из вариантов кода $[interface/lte/monitor lte1 once] вообще не добавляет данные или содержимое в сообщение (даже сам код не появляется). Это правильный способ получить данные MikroTik в отправляемом сообщении? Полученное сообщение прикреплено (извините, не могу приложить само сообщение) https://imgur.com/xlI5yVq

ОБНОВЛЕНИЕ: Зато этот вариант работает — message=“Mikrotik SXT перезагружен nPushover $[/system clock get time] $[/system clock get time] $[/system identity get name]”
09.07.2024 09:57:00, esj.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Sat, 28 Jun 2025 17:21:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
:global npushover
$npushover ({
user="private"
token="private"
message="Mikrotik SXT перезагрузился nPushover $[interface/lte/monitor lte1 duration=2]"
title="MikroTik SXTR"
html=1
sound="magic"
priority=0
url="https://192.168.x.1"
"url_title"="MikroTik"
})
… и оно выполняется, но в сообщении нет данных от LTE. Буду признателен за любые советы. Все команды с “monitor” хитрые, потому что это как “цикл for”… Поэтому нужно убрать “duration” и вместо него использовать “once”.

:global npushover
$npushover ({
user="private"
token="private"
message="Mikrotik SXT перезагрузился nPushover $[interface/lte/monitor lte1 once as-value]"
title="MikroTik SXTR"
html=1
sound="magic"
priority=0
url="https://192.168.x.1"
"url_title"="MikroTik"
})

“once” заставляет /interface/lte/monitor вернуть только один набор значений для вставки в сообщение. Можно использовать и duration, но тогда нужно сначала собрать данные monitor LTE в новую переменную, а потом использовать эту переменную в сообщении.
28.06.2025 17:21:00, Amm0.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Sun, 07 Jul 2024 16:50:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Спасибо, Amm0. Вопрос один: как добавить информацию из RouterOS в сообщение? Например, interface/lte/monitor lte1. Я пробовал так:

global npushover
$npushover ({
user="private"
token="private"
message="Mikrotik SXT перезагрузился nPushover $[interface/lte/monitor lte1 duration=2]"
title="MikroTik SXTR"
html=1
sound="magic"
priority=0
url="https://192.168.x.1"
"url_title"="MikroTik"
})

Он выполняется, но информация с LTE не появляется в сообщении. Буду признателен за любые подсказки.
07.07.2024 16:50:00, esj.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Sat, 06 Jul 2024 01:28:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Большое спасибо, Ammo, твой скрипт как раз кстати, ведь я узнал про Pushover всего два дня назад. Намного проще, чем Telegram. Спасибо, Dave.
06.07.2024 01:28:00, davorjs.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Sat, 28 Jun 2025 17:23:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Pushover также поддерживает JSON в качестве входных данных. За 5 лет с момента оригинального сообщения Mikrotik добавил поддержку JSON в скрипты RouterOS (начиная с версии 7.13). Хотя я уверен, что существующий скрипт работает нормально, я переписал его так, чтобы он принимал массив RouterOS с любыми значениями, разрешёнными API Pushover. Поскольку новый [:serialize] автоматически обрабатывает типы и экранирование при преобразовании массива RouterOS в JSON, который нужен Pushover, код становится значительно проще:

:global npushover do={
:local url "https://api.pushover.net/1/messages.json"
:local headers "Content-Type: application/json"
:local reqdata [:toarray ""]
:if ([:typeof $1]="array") do={:set reqdata $1} else={
:error "\$$0 требует массив значений, смотрите https://pushover.net/api"
}
:local json [:serialize to=json $reqdata]
:local resp [/tool/fetch url=$url http-data=$json http-header-field=$headers output=user as-value]
:local respdata [:deserialize from=json ($resp->"data")]
:if (($respdata->"status")=1) do={
/log/debug "$0 успешно отправил запрос $($respdata->"request")"
} else={
/log/warning "$0 неудача, получено: $[:tostr $resp]"
:error $resp
}
}

Чтобы отправить сообщение через pushover с помощью вышеописанной функции $npushover и массива, который допускает любые поддерживаемые атрибуты, включая url или priority, используйте так:

$npushover ({
user="u8xxxxxxxxxxx"
token="acyqxxxxxxxxxxxxxxx"
message="Возможно, немного HTML"
title="Тестовое сообщение"
html=1
sound="magic"
priority=0
url="https://router.lan/rest/system/resource"
"url_title"="/system/resources"
})

Смотрите https://pushover.net/api для возможных и разрешённых значений. Валидация не предусмотрена, так задумано. Ошибки выводятся и логируются, что должно помочь понять правильные значения. Такие параметры, как “priority”, могут иметь дополнительные атрибуты вроде “retry”, поэтому валидация может их блокировать или сильно усложниться.
28.06.2025 17:23:00, Amm0.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Mon, 01 Jul 2024 12:41:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Спасибо за скрипт. Работает отлично. Для теста я запускаю скрипт ниже: global pushover $pushover message=“Это простое сообщение Pushover.”
01.07.2024 12:41:00, esj.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Fri, 27 May 2022 07:29:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Я был полезен, понял? Вот теперь ты внимательно это прочитал…
27.05.2022 07:29:00, rextended.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Fri, 27 May 2022 02:03:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Публикация неясна. В ней не указано, куда именно это добавить. Правильный ответ был бы: добавьте :global pushover в скрипт, в котором вызывается $pushover. Не нужно быть занудой.
27.05.2022 02:03:00, RandyRiver88.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Thu, 26 May 2022 21:02:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Просто внимательно прочитайте предыдущее сообщение…
26.05.2022 21:02:00, rextended.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Thu, 26 May 2022 20:52:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Привет, где ты это исправил? У меня получается отправлять через терминал, но в скриптах нет... Можешь подсказать, какую строку нужно поменять? Спасибо.
26.05.2022 20:52:00, RandyRiver88.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Thu, 14 Oct 2021 05:35:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Команда $pushover message=“xyz” работает в терминале, но не работает в скриптах. Обновление: добавил :global pushover, и теперь могу использовать $pushover.
14.10.2021 05:35:00, Lilarcor.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Sat, 22 May 2021 01:33:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Я использую Telegram, чтобы получать сообщения от моего маршрутизатора. Pushover проще и удобнее в использовании?
22.05.2021 01:33:00, anav.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Fri, 21 May 2021 06:06:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Я пытался использовать это в net watch, но ничего не сработало, даже когда добавил keep-result=no в скрипт.
21.05.2021 06:06:00, Lilarcor.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Mon, 03 May 2021 10:04:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Потрясающе — спасибо!
03.05.2021 10:04:00, tmiklas.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Sun, 02 May 2021 00:43:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
@Belikearu, в Winbox или веб-интерфейсе это можно разместить в разделе System->Scripts. @dasiu, классный скрипт, как раз искал интеграцию с pushover.
02.05.2021 00:43:00, lacibsd.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Tue, 14 Apr 2020 23:37:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Как именно это сделать? Вставить скрипт в терминал Winbox? А что насчёт API-ключей? Не могли бы вы пояснить подробнее? Спасибо!
14.04.2020 23:37:00, Belikearu.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Tue, 14 Apr 2020 23:15:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Если в скрипте на команде fetch указать keep-result=no, всё работает. Также убедитесь, что для скриптов, которые запускаете через netwatch, установлена политика вроде policy=read,write,test.
14.04.2020 23:15:00, dreamind.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Tue, 03 Mar 2020 17:16:00 -0500

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Хорошо работает на FW 6.45.5, включая получение PUSHOVER через NETWATCH. На FW 6.46.4 работает только при ручном запуске скрипта для отправки PUSHOVER, но не работает отправка PUSHOVER из NETWATCH. Есть какие-то предложения?
03.03.2020 17:16:00, danielcada.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Wed, 03 Apr 2019 18:12:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Спасибо за это — этот кусок кода оказался очень полезным!
03.04.2019 18:12:00, cantanko.

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений

Thu, 28 Jun 2018 21:19:00 -0400

PUSHOVER — готовый скрипт для MikroTik для отправки сообщений RouterOS в форуме RouterOS.
Я только что написал скрипт (функцию), чтобы отправлять сообщения Pushover напрямую с MikroTik, без использования e-mail, а через прямое API (быстрее). Просто выполните один раз при загрузке для «установки» функций:

:global urlEncode do={
:local output ""
:local input [:toarray $1]
:if ([:len $input] > 0) do={
:local input1 [:tostr [:pick $input 0]]
:local conversion {" "="%20";"!"="%21";"\""="%22";"#"="%23";"\$"="%24";"%"="%25";"&"="%26";"'"="%27";"-"="%2D";"("="%28";")"="%29";"*"="%2A";"+"="%2B";","="%2C";"/"="%2F";":"="%3A";";"="%3B";"<"="%3C";">"="%3E";"="="%3D";"?"="%3F";"@"="%40";"["="%5B";"]"="%5D";"{"="%7B";"}"="%7D"};
:for i from=0 to=([:len $input1] - 1) do={
:local char [:pick $input1 $i]
:if ([:typeof ($conversion->[:tostr $char])]!="nothing") do={:set $char ($conversion->[:tostr $char]);}
:set output ($output . $char)
}
:set output [:tostr $output]
:set output [:toarray $output]
}
:return $output
}

:global pushover do={
:global urlEncode;
:if ([:typeof $message]!="nothing") do={
:local api "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
:local user "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
:local urlmessage [$urlEncode $message];
:local string "token=$api&user=$user&message=$urlmessage";
:if ([:typeof $title]!="nothing") do={:set $string ($string . "&title=$[$urlEncode $title]");}
:if ([:typeof $priority]!="nothing") do={:set $string ($string . "&priority=$priority");}
:if ([:typeof $sound]!="nothing") do={:set $string ($string . "&sound=$sound");}
/tool fetch mode=https url="https://api.pushover.net/1/messages.json" http-method=post http-data="$string";
}
}

Конечно, в переменных «api» и «user» у меня свои ключи от Pushover (вам нужно создать приложение в панели Pushover). Тогда я могу просто сделать:

$pushover message="Это простое сообщение Pushover."

Или более продвинуто:

:local title "Важное сообщение от роутера $[/system identity get name]";
:local message "Пишу, чтобы сообщить, что моя температура — $[/system health get temperature] градусов Цельсия!"
$pushover title=$title message=$message priority=1 sound="tugboat"

Я взял функцию urlEncode, которую написали несколько человек в этой ветке.
28.06.2018 21:19:00, dasiu.