Mikrotik.moscow [тема: Проверка значений рекурсивного маршрута]

Mikrotik.moscow [тема: Проверка значений рекурсивного маршрута] http://mikrotik.moscow Новое в теме Проверка значений рекурсивного маршрута форума RouterOS на сайте Mikrotik.moscow [mikrotik.moscow] ru http://backend.userland.com/rss2 Sat, 01 Aug 2026 08:16:30 -0400 Проверка значений рекурсивного маршрута Проверка значений рекурсивного маршрута RouterOS в форуме RouterOS.
@Amm0, огромное спасибо! Это реально помогло. Теперь всё работает. Я продолжу писать скрипт, который заменит то, что я делал раньше. Пример для других:

# Имя: onGatewayChange. Тестировано с ROS v7.9.2
# Добавьте в Scheduler и настройте на запуск каждые X секунд
# http://forum.mikrotik.com/t/checking-recursive-route-values/167746/1

# переменные для проверки маршрутов и других настроек
:local Route1 "8.8.8.8";
:local Route2 "9.9.9.9";
:local Route3 "10.10.10.10";
:local ISP1 "ISP1";
:local ISP2 "ISP2";

#####################################################################
# НАЧАЛО СКРИПТА
#####################################################################

# Системные переменные
:global GWORG;
:global GWCUR;
:local bFlag true;

# Получаем текущий адрес шлюза
:set GWCUR ([/ip route print detail as-value where active and routing-table="main"]->0->"gateway")

# 1: Всё ли осталось так же? Иначе ничего делать не нужно.
:if ( $GWCUR = $GWORG ) do={

# Ничего делать не надо. Окружение не изменилось.
#:log info "Нечего делать";
:set bFlag false;

} else={

:log info "*** onGatewayChange ***";

# Что-то изменилось. Мы на ISP1?
:if ( ($GWCUR = $Route1) || ($GWCUR = $Route2) ) do={

# Всё ещё на ISP1, а до этого тоже на ISP1?
:if ( ($GWORG = $Route1) || ($GWORG = $Route2) ) do={

# Это изменение значит, что мы всё ещё на ISP1. Обновлять не нужно.
:log info "Ещё на ISP1. Маршрут был $GWORG, теперь $GWCUR";
:set bFlag false;
}

# Всё ещё на ISP1, а пришли мы с ISP2?
:if ( $GWORG = $Route3 ) do={

# Это изменение означает возврат к ISP1. Сигнал на обновление.
:log info "Возврат к ISP1. Маршрут был $GWORG, теперь $GWCUR";
:set bFlag true;
}
}

# Что-то изменилось. Мы на ISP2?
:if ( $GWCUR = $Route3 ) do={

# Пришли ли мы с ISP1?
:if ( ($GWORG = $Route1) || ($GWORG = $Route2) ) do={

# Режим резервного копирования на ISP2
:log info "Режим резервного копирования на ISP2. Маршрут был $GWORG, теперь $GWCUR";
:set bFlag true;
}
}

}

# Выполняем переключение
:if ($bFlag = true) do={

# логируем изменения
:log info "Обработка события";

# Реакция в зависимости от ISP
:if ( ($GWCUR = $Route1) || ($GWCUR = $Route2) ) do={
:log info "Делаем что-то, теперь вы на ISP1."
} else={
:log info "Делаем что-то, теперь вы на ISP2."
}
}

# Обновляем глобальную переменную
:set $GWORG $GWCUR;
26.07.2023 15:55:00, pcunite.]]> http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423030 http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423030 Wed, 26 Jul 2023 15:55:00 -0400 RouterOS Проверка значений рекурсивного маршрута Проверка значений рекурсивного маршрута RouterOS в форуме RouterOS.
Почти... Думаю, это был долгий путь, чтобы сказать следующее: :put ([/ip route print detail as-value where comment="Example" and active and routing-table="main"]->0->"gateway"). Всегда нужны (скобки), если используешь оператор →. И, если используешь as-value, ничего не выведется, поэтому на командной строке нужен :put, чтобы увидеть значение. Можно сохранить как :local или :global без :put.

:global gw0 ([/ip route print detail as-value where comment="Example" and active and routing-table="main"]->0->"gateway")

:put $gw0

Или разбить так…

:global rtall ([/ip route print detail as-value where active and routing-table=main and comment~".*"])

# показываем длину (например, количество маршрутов, которые соответствуют условию "where")

:put [:len $rtall]

# первое совпадение...

:put ($rtall->0->"gateway")

:put ($rtall->0->"dst-address")

# второе совпадение

:put ($rtall->1->"gateway")

:put ($rtall->1->"dst-address")
26.07.2023 00:44:00, Amm0.]]> http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423029 http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423029 Wed, 26 Jul 2023 00:44:00 -0400 RouterOS Проверка значений рекурсивного маршрута Проверка значений рекурсивного маршрута RouterOS в форуме RouterOS.
Не мог бы ты показать мне универсальную версию этой команды, которая работает в терминале? У меня с этим трудности. /ip route print detail as-value where comment=“Example” and active and routing-table=“main”])->0->“gateway”
26.07.2023 00:03:00, pcunite.]]> http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423028 http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423028 Wed, 26 Jul 2023 00:03:00 -0400 RouterOS Проверка значений рекурсивного маршрута Проверка значений рекурсивного маршрута RouterOS в форуме RouterOS.
Не уверен, что ваша логика полностью верна, и не уверен, что мой код тоже идеален, даже если бы был — у меня нет настроенного RR для теста… Но вот что я заметил с первого взгляда.

Имя: onGatewayChange
Добавить в Scheduler и запускать каждые 10 секунд

> Проверка значений Recursive Route, переменные для хранения проверок маршрутов и других данных:
:local sHost1 “8.8.8.8”;
:local sHost2 “9.9.9.9”;
:local sHost1Str “ISP1_GW”;
:local sHost2Str “ISP2_GW”;

Глобальные переменные для мониторинга через System/Scripts GUI:
:global sGateway1;
:global sGateway2;

Получить текущее значение шлюза:
:local sGateway1Current > ( > [ip route print > as-value > where comment=“$sHost1Str” and active and routing-table=“main”]> )->0->“gateway”)

Отладка:
:log info “Start”;
:log info “$sGateway1Current”;

1: Текущее состояние окружения:
:if ( ($sGateway1Current = $sHost1) || ($sGateway1Current = $sHost2) ) do={
:log info “$sGateway1Current”;
:log info “$sHost1Str в работе”;
} else={
:if > ( [:typeof $sGateway1Current] = nothing ) > do={
:log info “$sHost1Str пуст, значит скорее всего активен маршрут 2”;
// делаем другие действия
}
}

\ debug :log info “Finished”;

Возможно, лучше сначала ответить на первую часть вашего вопроса… Учить человека рыбачить… Может, это поможет…

В общем, всегда нужно использовать “->” (оператор доступа), обязательно обрамлённый скобками (), чтобы группировать, к какому элементу массива происходит обращение. Сам оператор доступа может принимать число или строку — в зависимости от структуры массива.

Структура массива может быть либо “упорядоченным списком”, либо “словарием” (map).

Упорядоченный список имеет порядок, который не меняется, и начинается с индекса 0.

В словарной структуре есть “ключи” и “значения”.

Аналогия с конфигом: команда “find” создаёт упорядоченный список, а “get” (без атрибута) возвращает словарь.

Пара примеров поможет понять философию массивов…

Простой пример упорядоченного списка:
{
# упорядоченные списки объявляются в {} через ; и могут содержать данные любых типов
:local orderedList {"cat";"dog";3;8.8.8.8}

:put ($orderedList->0)
#cat
:put ($orderedList->1)
#dog
:put ($orderedList->2)
#3
:put [:typeof ($orderedList->3)]
#ip
:put [:typeof ($orderedList->4)]
#nothing — ведь такого индекса нет, и тип у него на самом деле ничего, а не строка или что-то другое...
}

Пример — получение первого элемента из массива, возвращённого командой
print обычно выводит в консоль и по умолчанию не возвращает массив, поэтому нужно использовать “as-value”, чтобы заставить её вернуть массив. При использовании “as-value” возращается упорядоченный список, к которому обращаются по числу. Значит ->0 — это первый элемент массива…

:put ([/ip route print as-value where active]->0)

Но что если список пуст… Так как может не быть активных маршрутов… тогда нужно хранить и проверять это:
{
:local allRoutes [/ip route print as-value where active]
# один способ — использовать :len, чтобы понять, нужно ли брать первый элемент…
:if ([:len $allRoutes] > 0) do={:put ($allRoutes->0)}
# или проверить, что по типу это не “ничего”...
:if ([:typeof ($allRoutes->0)] != "nothing") do={:put ($allRoutes->0))
}

Простой пример словаря (map), например, с “ключ=значение”
Они работают так, что задаётся ключ (имя атрибута) через = и значение, атрибуты разделяются точкой с запятой. Часть до = — к ней обращаются, часть после = — что возвращается. Нужно брать имя атрибута в кавычки. Индексы вроде ->0 для “первого” атрибута использовать нельзя — словарь хранится в алфавитном порядке и не имеет индекса.

{
:local vlanspecs {vid=10;type="access"}
:put ($vlanspecs->"vid")
:put ($vlanspecs->"type")
:put [:typeof ($vlanspecs->"somethingnotthere")]
}

Список словарей — или цикл по таблице маршрутов
Для веселья… массивы могут быть “вложенными” — список может содержать в себе словарь как один из элементов. Правило одно: на любом “уровне” у массива либо список, либо словарь — одновременно нельзя. Но список может содержать словари в качестве значений, а словарь может иметь значения в виде списка (или даже другого словаря).

Упорядоченный список — это то, что возвращает “print as-value”. Внутри списка — словарь с атрибутами.

RouterOS :foreach поможет перебрать все значения из “списка словарей” (list):

{
:foreach foundItem in=[/ip/route/print as-value] do={
# вывести все атрибуты текущего маршрута в цикле
:put $foundItem
# вывести только атрибут comment — обратите внимание на кавычки, потому что каждый маршрут — это словарь
:put ($foundItem->"comment")

# так как $foundItem — это словарь…
# можно пройтись и получить И имя атрибута, И значение для текущего маршрута
:foreach routeAttr,attrValue in=$foundItem do={
:put "$routeAttr установлено в $attrValue"
}
}
}

Сообщите, если будут ещё вопросы.
25.07.2023 19:54:00, Amm0.]]> http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423027 http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423027 Tue, 25 Jul 2023 19:54:00 -0400 RouterOS Проверка значений рекурсивного маршрута Проверка значений рекурсивного маршрута RouterOS в форуме RouterOS.
@Ammo, большое спасибо. Кажется, я нашёл для себя обходной путь. Как только всё сделаю, выложу. А пока можешь помочь с частью скрипта? Ниже мой пример скрипта. Вопросы: я не знаю, как выбирать данные в ROS. В логике примера показано, как получить данные ip route для рекурсивного маршрута ISP1 (по совпадению комментария и активного состояния). Это даёт мне таблицу данных. Хотелось бы из этой таблицы выбрать только столбец GATEWAY, если это возможно, чтобы получить простую строку (не массив). Круто, что если команда вернёт пустую строку, значит я не на рекурсивном маршруте ISP1. Это всего лишь пример, позже покажу более сложную логику, как запущу. Поможешь, чтобы этот скрипт работал?

# Name: onGatewayChange
# Добавить в планировщик и запускать каждые 10 секунд
# http://forum.mikrotik.com/t/checking-recursive-route-values/167746/1

# переменные для проверки маршрутов и прочего
:local sHost1 "8.8.8.8";
:local sHost2 "9.9.9.9";
:local sHost1Str "ISP1_GW";
:local sHost2Str "ISP2_GW";

# глобальные переменные для мониторинга через System/Scripts GUI
:global sGateway1;
:global sGateway2;

# получаем текущее значение шлюза
:local sGateway1Current [ip route print where comment="$sHost1Str" and active and routing-table="main"];

# отладка
:log info "Start";
:log info "$sGateway1Current";

# 1: текущее состояние среды
:if (($sGateway1Current = $sHost1) || ($sGateway1Current = $sHost2)) do={
:log info "$sGateway1Current";
:log info "$sHost1Str активен";
} else={
:if ($sGateway1Current = "") do={
:log info "$sHost1Str пустой, значит скорее всего активен маршрут 2";
# делать другое
}
}

# отладка
:log info "Finished";
25.07.2023 18:01:00, pcunite.]]> http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423026 http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423026 Tue, 25 Jul 2023 18:01:00 -0400 RouterOS Проверка значений рекурсивного маршрута Проверка значений рекурсивного маршрута RouterOS в форуме RouterOS.
В версии V7 убрали команду «/ip route check». Полагаю, в V6 она использовала кэш маршрутов, а поскольку в V7 кэша маршрутов нет, команду просто убрали, вместо того чтобы исправлять. Очень неудобно в ситуациях с «multi-WAN», особенно когда речь идёт о рекурсивных маршрутах. Подробнее здесь: http://forum.mikrotik.com/t/ip-route-check-command-disappeared/141645/1
23.07.2023 17:20:00, Amm0.]]> http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423025 http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423025 Sun, 23 Jul 2023 17:20:00 -0400 RouterOS Проверка значений рекурсивного маршрута Проверка значений рекурсивного маршрута RouterOS в форуме RouterOS.
Как определить, какой рекурсивный маршрут активен?
19.07.2023 18:43:00, pcunite.]]> http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423024 http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423024 Wed, 19 Jul 2023 18:43:00 -0400 RouterOS Проверка значений рекурсивного маршрута Проверка значений рекурсивного маршрута RouterOS в форуме RouterOS.
Я использовал следующий кусок скрипта, чтобы получить статус рекурсивных маршрутов в настройках MultiWAN. Отлично работает на ROS v6, но уже не совместим с ROS v7. Я использую эти значения, чтобы определить, какой рекурсивный маршрут сейчас активен/используется по умолчанию, а затем вношу изменения в другие части роутера. Может, есть более правильный способ сделать это? Кто-нибудь знает, как теперь получить эту информацию? В ROS v7 как узнать, какой рекурсивный маршрут является маршрутом по умолчанию?

# Переменные маршрута
:local sHost1 "8.8.8.8";
:local sHost2 "9.9.9.9";

# Получить текущие адреса шлюзов
:local sGWCur1 [ip route get [find active=yes 0.0.0.0/0 in dst-address !routing-mark] gateway]
:local sGWCur2 ([ip route check $sHost1 once as-value]->"nexthop")
:local sGWCur3 ([ip route check $sHost2 once as-value]->"nexthop")
29.06.2023 22:37:00, pcunite.]]> http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423023 http://mikrotik.moscow/forum/forum57/88058-proverka-znacheniy-rekursivnogo-marshruta/message423023 Thu, 29 Jun 2023 22:37:00 -0400 RouterOS