Обновление No-IP и DNSdynamic

Отличный рабочий скрипт для обновления DDNS NO-IP совместно с DNSdynamic Services. Отладка и проверка проведены. Сделано из-за ненадёжности долгосрочной работы без подтверждения на сервисе NO-IP. Извиняюсь за мой плохой английский. #No-IP #DNSdynamic update

#--------------- Измените значения в этом разделе под вашу конфигурацию ------------------

#Информация об учётной записи пользователя
:local noipuser "NO-IP_User_Name"
:local noippass "NO-IP_password"
:local dnsdynamicuser "DNSdynamic_User_Name"
:local dnsdynamicpass "DNSdynamic_password"
:local noiphost "NO-IP_host"
:local dnsdynamichost "DNSdynamic_host"

# Укажите название интерфейса, который получает динамический IP-адрес
:local inetinterface "Internet_Interface_Name"

#------------------- Больше изменений не требуется --------------------------------------

:global previousIP

:if ([/interface get $inetinterface value-name=running]) do={
# Получаем текущий IP на интерфейсе
  :local currentIP [/ip address get [find interface="$inetinterface" disabled=no] address]

# Отрезаем маску подсети от IP-адреса
  :for i from=( [:len $currentIP] - 1) to=0 do={
      :if ( [:pick $currentIP $i] = "/") do={
          :set currentIP [:pick $currentIP 0 $i]
      }
  }

  :if ($currentIP != $previousIP) do={
      :log info "IP: Текущий IP $currentIP не равен предыдущему IP, требуется обновление"
      :set previousIP $currentIP

# URL обновления No-Ip. Обратите внимание, что "\3F" — это шестнадцатеричный код знака вопроса (?), он нужен, так как ? — специальный символ в командах.
      :local url "http://dynupdate.no-ip.com/nic/update\3Fmyip=$currentIP"
      :local noiphostarray
      :set noiphostarray [:toarray $noiphost]
      :foreach host in=$noiphostarray do={
          :log info "No-IP: Отправка обновления для $host"
          /tool fetch url=($url . "&hostname=$host") user=$noipuser password=$noippass mode=http dst-path=("no-ip_ddns_update-" . $host . ".txt")
          :log info "No-IP: Хост $host обновлён на No-IP с IP $currentIP"
      }

# URL обновления dnsdynamic. Обратите внимание, что "\3F" — это шестнадцатеричный код знака вопроса (?), он нужен, так как ? — специальный символ в командах.
      :local url "https://www.dnsdynamic.org/nic/nic/update\3Fmyip=$currentIP"
      :local dnsdynamichostarray
      :set dnsdynamichostarray [:toarray $dnsdynamichost]
      :foreach host in=$dnsdynamichostarray do={
          :log info "dnsdynamic: Отправка обновления для $host"
          /tool fetch url=($url . "&hostname=$host") user=$dnsdynamicuser password=$dnsdynamicpass mode=http dst-path=("dnsdynamic_ddns_update-" . $host . ".txt")
          :log info "dnsdynamic: Хост $host обновлён на dnsdynamic с IP $currentIP"
      }
  } else={
      :log info "IP: Предыдущий IP $previousIP равен текущему IP, обновление не требуется"
  }
} else={
  :log info "IP: Интерфейс $inetinterface сейчас не активен, обновление не выполняется."
}