Добавить значения VLAN моста

LOL. Похоже, за последние 3 года мало кто пытался написать скрипт для существующих trunk-портов моста… Проблема в том, что атрибут vlan-ids в /interface/bridge/vlan — это МАССИВ, поэтому [find vlan-ids=10] не работает с массивом. Я надеялся, что что-то упустил, но поиск в Google и на форуме ничего не подсказал. Зато, по крайней мере с версии 7.16, access-порты можно автоматически обрабатывать с помощью «динамических» записей, создаваемых /interface/vlan и установки pvid= на /interface/bridge/port — так что эта часть стала проще (добавление L3 /interface/vlan на vlan-бридж автоматически добавит bridged в динамический tagged=), то есть одна правка стала лишней.

Но скрипт для «добавления tagged-порта» далеко не простой, и я всё ещё над ним работаю... Вот как я сюда и попал. Я пытался создавать «автоматизированные» скрипты для VLAN на мосту (см. часть 1: http://forum.mikrotik.com/t/example-of-automating-vlan-creation-removal-inspecting-using-mkvlan-friends/181480/6), а часть 2 со скриптами для управления «bridge vlan filtering» — куда сложнее.  

Единственный способ, который я нашёл, — это сложный код, который перебирает «dynamic=no» в /interface/bridge/vlans, затем с помощью foreach перебирает массив vlan-ids, чтобы проверить совпадения с искомым VLAN, и тогда делает SET (если совпадений нет — после двух циклов делает ADD нового /interface/bridge/vlan). Если кто-то знает способ получше или хитрость — очень интересно было бы узнать.

LOL, я думал, что какой-то трюк с [find (code)] сработает — проблема была именно в вложенном :find внутри find, о котором я не подумал. Отличная работа! Теперь, стоит ли "языку конфигурации" для роутера превращать добавление access/trunk-портов в задачу уровня LeetCode — это уже совсем другой вопрос. По моему мнению, нужен оператор find для проверки вхождения в массив, типа “[find vlan-id has <VLAN_ID>]”. Сейчас есть оператор “in”, но он работает только для ip-prefix. Например, даже с ярлыком @optio всё не очень аккуратно, а удаление ещё сложнее. Думаю, вот такой подход с тегированием порта на VLAN — без тонны :foreach — правильный, но надо бы подробнее протестировать, чтобы быть уверенным:

:global mktrunk do={
   :local bvid [/interface/bridge/vlan find dynamic=no vlan-ids=[:if ([:len [:find $"vlan-ids" $1]]) do={:return $"vlan-ids"}]]
   :if ([:len $bvid]=0) do={
       :set bvid [/interface/bridge/vlan add vlan-ids=$1 comment="added by $0" bridge=[/interface/bridge/find vlan-filtering=yes disabled=no]]
   }
   /interface/bridge/vlan set $bvid tagged=([get $bvid tagged],$2)
}

:global rmtrunk do={
   :local bvid [/interface/bridge/vlan find dynamic=no vlan-ids=[:if ([:len [:find $"vlan-ids" $1]]) do={:return $"vlan-ids"}]]
   :local orig [/interface/bridge/vlan get $bvid tagged]
   :local final [:toarray ""]
   :foreach i in=$orig do={ :if ($i != "$2") do={:set final ($final, $i)} }
   /interface/bridge/vlan set $bvid tagged=$final
   # опционально, если больше нет тегированных или нетегированных портов — удалить сам bridge vlan
   :if (([:len [/interface/bridge/vlan get $bvid tagged]]=0) and ([:len [/interface/bridge/vlan get $bvid untagged]]=0)) do={
       /interface/bridge/vlan remove $bvid
   }
   # в то время как mktrunk может принимать массив интерфейсов, rmtrunk должен получать только один интерфейс в $2
}

# создать
$mktrunk 123 ether4
# обновить
$mktrunk 123 ether5
# удалить
$rmtrunk 123 ether5
# примечание: массив поддерживается только для mktrunk, так как там это автоматом
$mktrunk 123 ("ether5","ether6")
# а rmtrunk МАССИВ не принимает и вообще ничего не найдёт/не удалит

В любом случае, вышеприведённый код намного чище, чем то, с чего я начинал… Так что спасибо!

Не уверен, что это то, о чем ты говоришь, но я искал способ добавить порты моста в существующую VLAN через CLI.

:local vlanId 30  
:local bridgeName "bridge"  
:local newPort "sfp-sfpplus3"  

:local vlanEntry [/interface bridge vlan find where bridge=$bridgeName and vlan-ids=$vlanId]

:local currentTagged [/interface bridge vlan get $vlanEntry tagged]
:put [:len $currentTagged]

:if ([:len $currentTagged] > 0) do={
   :local updatedTagged ($currentTagged, $newPort)  
   /interface bridge vlan set $vlanEntry tagged=$updatedTagged  
} else={  
   /interface bridge vlan set $vlanEntry tagged=$newPort  
}  

:put ("Порт " . $newPort . " добавлен в VLAN " . $vlanId . " как tagged.")